Add Mix.Gleam module to parse toml config

Author: Rodrigo Álvarez

lib/mix/lib/mix/gleam.ex

@@ -0,0 +1,50 @@
+defmodule Mix.Gleam do
+  def load_config(dir) do
+    config_path = Path.join(dir, "gleam.toml")
+
+    case File.read(config_path) do
+      {:ok, config} ->
+        parse_config(config)
+
+      {:error, :enoent} ->
+        []
+
+      {:error, error} ->
+        raise("Error reading gleam.toml config #{inspect(config_path)}: #{error}")
+    end
+  end
+
+  defp parse_config(config) do
+    dependencies =
+      config
+      |> table("dependencies")
+      |> parse_deps()
+
+    dev_dependencies =
+      config
+      |> table("dev-dependencies")
+      |> parse_deps
+      |> Enum.map(&Tuple.insert_at(&1, 2, only: :dev))
+
+    %{
+      deps: dependencies ++ dev_dependencies
+    }
+  end
+
+  # Given a string of deps, returns them as a list of tuples
+  defp parse_deps(string) do
+    ~r/^([a-z][a-z0-9_]+)\s*=\s*"([^"]+)"\s*/m
+    |> Regex.scan(string)
+    |> Enum.map(fn dep ->
+      [_, name, version] = dep
+      {String.to_atom(name), version}
+    end)
+  end
+
+  # Grabs a TOML table by name and returns its contents as a string
+  def table(config, name) do
+    ~r/^\[#{name}\]$[\r\n]+((?:[a-z][a-z0-9_]*\s*=\s*"[^"]+"\r?\n?)+)/m
+    |> Regex.run(config)
+    |> List.last()
+  end
+end

lib/mix/test/mix/gleam_test.exs

@@ -0,0 +1,36 @@
+# SPDX-License-Identifier: Apache-2.0
+# SPDX-FileCopyrightText: 2021 The Elixir Team
+# SPDX-FileCopyrightText: 2012 Plataformatec
+
+Code.require_file("../test_helper.exs", __DIR__)
+
+defmodule Mix.GleamTest do
+  use MixTest.Case
+
+  @compile {:no_warn_undefined, [:gleam_dep, :gleam@int]}
+
+  defmodule GleamAsDep do
+    def project do
+      [
+        app: :gleam_as_dep,
+        version: "0.1.0",
+        deps: [
+          {:gleam_dep, path: MixTest.Case.tmp_path("gleam_dep"), app: false}
+        ]
+      ]
+    end
+  end
+
+  describe "load_config/1" do
+    test "loads gleam.toml" do
+      path = MixTest.Case.fixture_path("gleam_dep")
+      config = Mix.Gleam.load_config(path)
+
+      assert config[:deps] == [
+               {:gleam_stdlib, ">= 0.44.0 and < 2.0.0"},
+               {:gleam_otp, ">= 0.16.1 and < 1.0.0"},
+               {:gleeunit, ">= 1.0.0 and < 2.0.0", only: :dev}
+             ]
+    end
+  end
+end